I've downloaded PrimerMouse 1.0 but can't get it to install (I have already upgraded to CircleOS 1.6 and loaded the other applications ok), I have used "add_to_Circle.bat" but I get "Error: No o. file has been found. Aborting". Anyone else had any problems with installing this?
I have updated the main batch file. Please open the file "C:\Program Files\Raisonance\Ride\Bin\add_CircleOS_application.bat" (or equivalent path) and replace its content by the following:
Code:
@echo off
set FILETOPROGRAM=
rem check that there is only one .lib file.
if exist __add_CircleOS_application.tmp del /F __add_CircleOS_application.tmp
for %%i in (*.lib) do (
set FILETOPROGRAM=%%i
if exist __add_CircleOS_application.tmp goto error
echo a > __add_CircleOS_application.tmp
)
rem If the .tmp file exists, one .lib file is present.
if exist __add_CircleOS_application.tmp goto program
rem Else, we must check that there is only one .o file...
for %%i in (*.o) do (
set FILETOPROGRAM=%%i
if exist __add_CircleOS_application.tmp goto error
echo a > __add_CircleOS_application.tmp
)
rem If the .tmp file exists, one .o file is present.
if exist __add_CircleOS_application.tmp goto program
rem No object file found
echo Error: No .lib or .o file has been found. Aborting.
goto end
rem program the .o or .lib file.
:program
echo.
echo *** Launching : circle_mgr.exe A%FILETOPROGRAM% L S
echo.
circle_mgr.exe A%FILETOPROGRAM% L S
goto end
:error
echo Error: Several .o or .lib files are present in the directory. Aborting.
goto end
:end
if exist __add_CircleOS_application.tmp del /F __add_CircleOS_application.tmp
set FILETOPROGRAM=
echo.
pause
